home *** CD-ROM | disk | FTP | other *** search
/ Magnum One / Magnum One (Mid-American Digital) (Disc Manufacturing).iso / d12 / vol7n3.arc / PP703.ARC / ATOI.ASM next >
Assembly Source File  |  1988-01-08  |  3KB  |  88 lines
  1.         name    atoi
  2.         page    55,132
  3.         title   ATOI - ASCII to integer
  4.  
  5. ;
  6. ; ATOI.ASM - convert ASCII string to 
  7. ;            16-bit decimal integer.
  8. ;
  9. ; Copyright 1987 Ziff Communications Co.
  10. ; Ray Duncan
  11. ; 
  12. ; Call with:    DS:SI = address of string
  13. ;
  14. ;               where 'string' is in the form
  15. ;               
  16. ;                  [whitespace][sign][digits]
  17. ;
  18. ; Returns:      AX    = result
  19. ;               DS:SI = address+1 of terminator 
  20. ;
  21. ;               other registers preserved
  22. ;
  23. ; Like the C library 'atoi', this routine gives no 
  24. ; warning in the event of overflow, and terminates 
  25. ; on the first invalid character.
  26. ;
  27.  
  28. blank   equ     20h             ; ASCII blank character
  29. tab     equ     09h             ; ASCII tab character
  30.  
  31. _TEXT   segment word public 'CODE'
  32.  
  33.         assume  cs:_TEXT
  34.  
  35.         public  atoi
  36. atoi    proc    near            ; ASCII to 16-bit integer
  37.  
  38.         push    bx              ; save registers
  39.         push    cx
  40.         push    dx
  41.  
  42.         xor     bx,bx           ; initialize forming answer
  43.         xor     cx,cx           ; initialize sign flag
  44.  
  45. atoi1:  lodsb                   ; scan off whitespace
  46.         cmp     al,blank        ; ignore leading blanks
  47.         je      atoi1
  48.         cmp     al,tab          ; ignore leading tabs
  49.         je      atoi1
  50.  
  51.         cmp     al,'+'          ; if + sign proceed
  52.         je      atoi2
  53.         cmp     al,'-'          ; is it - sign?
  54.         jne     atoi3           ; no, test if numeric
  55.         dec     cx              ; was - sign, set flag
  56.                                 ; for negative result
  57.  
  58. atoi2:  lodsb                   ; get next character
  59.  
  60. atoi3:  cmp     al,'0'          ; is character valid?
  61.         jb      atoi4           ; jump if not '0' to '9'
  62.         cmp     al,'9'
  63.         ja      atoi4           ; jump if not '0' to '9'
  64.  
  65.         and     ax,0fh          ; isolate lower four bits
  66.  
  67.         xchg    bx,ax           ; multiply answer x 10
  68.         mov     dx,10
  69.         mul     dx
  70.  
  71.         add     bx,ax           ; add this digit
  72.  
  73.         jmp     atoi2           ; convert next digit
  74.  
  75. atoi4:  mov     ax,bx           ; result into AX
  76.         jcxz    atoi5           ; jump if sign flag clear
  77.         neg     ax              ; make result negative
  78.  
  79. atoi5:  pop     dx              ; restore registers
  80.         pop     cx
  81.         pop     bx
  82.         ret                     ; back to caller
  83.  
  84. atoi    endp
  85.  
  86. _TEXT   ends
  87.         end
  88.